Parsing Text File By Column Pattern

Question

I was wondering if there is an easy way to use awk or any other command to parse a text file such that a file of something like:

Step Temp Enthalpy
0    0    -368
100  1    -369
200  2    -372
300  6    -362
400  9    -365
SHAKE stats (type/ave/delta) on step 500
1 1.09  8.71362e-08
500  13   -358
600  15   -339
.
.
900  25   -306
SHAKE stats (type/ave/delta) on step 1000
1 1.09 7.06858e-08
1000 28  -306
.
.
.

could print an output of only the specific column of numbers I want such as only the temperature values. I know I could just do something like awk '{print $2}' for the temperature values but my particular data file has other lines of various data before and after the 'Step Temp Enthalpy' table that makes this impractical so I'd like to ideally cut out everything before and after this 'Step Temp Enthalpy' information and print out only the particular column of this section of the data file I need. The data file also has that 'SHAKE stats' line every 5 steps in addition to a line after it '1 1.09 ....etc' that I'd like removed. If I were to print only the temperature column I'd like it to output:

0
1
2
6
9
13
15
.
.
25
28

Answer 1

The simple pattern that you have is to take out column 2 in lines containing/starting with digits. The usual structure of awk commands is /Pattern in current line/ { commands};. The commands in braces are executed only if pattern is found in current line. Therefore we can do:

$ awk '/^[[:digit:]]/{print $2}' input.txt
0
1
2
6
9
1.09
13
15
25
1.09
28

To also remove the floating point numbers, add extra pattern with logical AND operator &&:

$ awk '/^[[:digit:]]/ && $0 !~ /[.]/ {print $2}' input.txt
0
1
2
6
9
13
15
25
28

Alternatively, just use a negation pattern to exclude shake stats:

awk '!/^SHAKE/ && $0 !~ /[.]/ {print $2}' input.txt 

To address the question in the comment, you can combine range pattern ( something like /Pattern1/,/Pattern2/ {commands} ) with and if statement. The range pattern will perform commands within curly braces only for lines fitting the range, and then if statement can do extra filtering. In this particular case, you can simply combine it with previous solution like so:

$ awk '$0 == "Step Temp Enthalpy",0 { if( $0 ~ /^[[:digit:]]/ && $0 !~ /[.]/  ) print $2  }' input.txt

The pattern $0 == "Step Temp Enthalpy",0 signifies processing of the exact line Step Temp Enthalpy to 0, that is end of file.

Answer 2

Here's a (possibly) simpler approach based on the structure of the data rather than on matching the content:

• use modulo arithmetic to test whether we are on one of the SHAKE stats lines
• if so, slurp up the next line with getline and move on
• otherwise, print the second field

So

$ awk '!(NR%7) {getline; next} {print $2}' data
Temp
0
1
2
6
9
13
15


25
28